Internet 1996 World Exposition/park.org.s3.amazonaws.com.7z/park.org.s3.amazonaws.com/Japan/Panasonic-/funcity/tokyo/flagirl.dcr/00002_girl script.ls

Text File | 2017-09-21 | 2.8 KB | 100 lines

property acount, snum, cnum, animstep
global getlinggirlnum

on birth me, lh, lv, sanum
  set snum to sanum
  set cnum to the number of cast "g_de.loop"
  set the puppet of sprite snum to 1
  set the type of sprite snum to 1
  set the castNum of sprite snum to cnum
  set the ink of sprite snum to 36
  set the foreColor of sprite snum to 255
  set the backColor of sprite snum to 0
  set the locH of sprite snum to lh
  set the locV of sprite snum to lv
  set animstep to 0
  return me
end

on getling me
  if getlinggirlnum >= 9 then
    exit
  end if
  if cnum <> the number of cast "g_de.loop" then
    puppetSound("ops")
    exit
  end if
  set cnum to the number of cast "g_ling.loop"
  set the castNum of sprite snum to cnum
  set animstep to 50
  set ccnum to the number of cast "getLingGirl"
  set getlinggirlnum to getlinggirlnum + 1
  set the puppet of sprite (getlinggirlnum + 7) to 1
  set the blend of sprite (getlinggirlnum + 7) to 100
  set the stretch of sprite (getlinggirlnum + 7) to 1
  set the castNum of sprite (getlinggirlnum + 7) to ccnum
  set the height of sprite (getlinggirlnum + 7) to the height of cast ccnum / 2
  set the width of sprite (getlinggirlnum + 7) to the width of cast ccnum / 2
  puppetSound("win")
  puppetSound(2, the number of cast "bgm")
  if getlinggirlnum >= 9 then
    showscore()
  end if
end

on changegirl me
  set animstep to animstep - 1
  if animstep > 0 then
    exit
  end if
  if cnum = the number of cast "g_ling.loop" then
    if random(2) = 1 then
      if random(4) = 1 then
        set cnum to the number of cast "g_fall.loop"
      else
        set cnum to the number of cast "g_miss.loop"
      end if
      set the castNum of sprite snum to cnum
    end if
    set animstep to 10
  else
    if cnum = the number of cast "g_fall.loop" then
      set cnum to the number of cast "g_re.loop"
      set the castNum of sprite snum to cnum
      set animstep to 12
    else
      if cnum = the number of cast "g_miss.loop" then
        set cnum to the number of cast "g_de.loop"
        set the castNum of sprite snum to cnum
      else
        if cnum = the number of cast "g_re.loop" then
          set cnum to the number of cast "g_ling.loop"
          set the castNum of sprite snum to cnum
          puppetSound(2, the number of cast "bgm")
          set animstep to 30
        end if
      end if
    end if
  end if
end

on setdegirl me
  if cnum = the number of cast "g_ling.loop" then
    exit
  end if
  set cnum to the number of cast "g_de.loop"
  set the castNum of sprite snum to cnum
end

on setloopgirl me
  set cnum to the number of cast "g_ling.loop"
  set the castNum of sprite snum to cnum
  set animstep to 40
end

on setmissgirl me
  set cnum to the number of cast "g_miss.loop"
  set the castNum of sprite snum to cnum
  set animstep to 10
end